balken in der tabelle werden nicht dargestellt (mit beispiel)

[Mr.Twister]

hi,
ich hatte gestern ja schonmal geschrieben, aber es ist leider recht dringend, und ich befürchte, daß mir im alten thread keiner mehr antworten wird.

also:
in der rar-datei gibt es die datei "test2.fla". die funktioniert in sich okay.
wenn ich die daraus entstandene swf aber in test1 per loadMovie lade, werden die balken der tabelle nicht mehr dargestellt.

BITTE BITTE helft mir, ich kann mir das absolut nicht erklären und habe schon viel probiert.

danke für hilfe!

Du bist auf den alten "_root"-Objektpfadfehler reingefallen. Dein Balken-MC wird mit der _root-Pfadangabe auf der falschen Hauptzeitleiste erstellt, mach es besser so:

_global.dZ = this;
_global.dZ.createEmptyMovieClip("balkenMC", 4000); 

[Janoscharlipp]

hier ein aufgeräumtes Script für test2:
Grundsätzlich solltest du genau auf deine Pfade achten, besser den Pfad genau beschreiben (this., _root. …) als sich auf Flash verlassen!

//#include "lmc_tween.as"
this.animType = "easeInOutQuad";
this.animSpeed = 1;
this.rand2 = 120;
this.balkenAbstand = 60;
////////////////////////////////////////////////////////
this.tiefe2 = 5000;
this.createEmptyMovieClip("balkenMC", 4000);
//XML laden
 
this.buildDiagramm = function(nodeMain) {
    for (var j in this.balkenMC) {
        this.balkenMC[j].removeMovieClip();
    }
    
    this.xmlDatei2 = "diagramm.xml";
    this.xmlDiagramm = new XML();
    this.xmlDiagramm.ignoreWhite = true;
    this.xmlDiagramm.load(xmlDatei2);
    
    // timeline für das Event hinterlegen
    // Suche im FlashForum: closure
    var timeline = this;
    
    this.xmlDiagramm.onLoad = function(success) {
        if (success) {
            var anzahl2 = this.childNodes[0].childNodes.length;
            var i;
            
            for (i=0; i<anzahl2; i++) {
                timeline.balkenMC.attachMovie("balken", "balken"+i, timeline.tiefe2++);
                timeline.balkenMC["balken"+i]._x = timeline.rand2 + timeline.balkenAbstand * i;
                timeline.balkenMC["balken"+i]._y = 360;
                
                // Achtung: sei dir dessen bewusst, das nodeMain nur per Closure vorhanden ist!
                // ist das so gewollt?
                timeline.balkenMC["balken"+i]._yscale = Number(this.childNodes[nodeMain].childNodes[i].attributes.value1);
            }
            // keien Ahnung nun passieren soll.
            //txt_name.text = xmlDiagramm.childNodes[nodeMain].childNodes[0].attributes.value2;
        }
    };
};
 
this.buildDiagramm(0); 

[Mr.Twister]

OOOOHHHH, mensch leute, ihr seid einfach die besten!! *g*

vielen dank an euch!