attachMovie Problem

[keulche]

Hallo, mein Ziel ist es sobald ich auf die SPACE-Taste drücke, soll eine neue Instanz des Movieclips "schuss" erzeugt werden.
Der neue Movieclip soll dann in -Y Richtung wandern( tut er auch)

Mein Problem, sobald ich die Leertaste drücke wird der vorher erzeugt MC nicht mehr fertig abgespielt bzw. er wird wieder zurückgesetzt.
Es soll also so sein, dass alle erzeugte MovieClips fertig abgespielt werden und mit der Leertaste ein neuer erzeugt wird, der den anderen "verfolgt".

Hier mein Code und die FLA ist im Anhang:

onClipEvent (enterFrame){
if (Key.isDown (Key.SPACE)) {
_root.attachMovie("schuss","s1"+i,i);
_root["s1"+i]._y=_root.ship1._y;
_root["s1"+i]._x=_root.ship1._x+30;
}// End IF


_root["s1"+i]._y-=3;


}//End EnterFrame

onClipEvent(load){
i=600;
}//End Load

[Alphanimal]

"i" ist bei dir konstant 600
warum gerade 600??

du brauchst für jeden erstellten MC eine eigene tiefe, wenn du einen MC auf einer Tiefe erzeugst auf der sich schon ein anderer MC befindet wird dieser gelöscht und mit dem neuen überschieben.

d.h. du müsstest i bei jedem schuss ändern

ein i++ nach dem attachMovie und nachdem du alle eigenschaften (_x, _y) des neuen MCs gesetzt hast reicht dafür!

jetzt musst du noch alle bisher erzeugten schüsse einzelt bewegen, am besten mit einer schleife.

oder du baust den Code zum Bewegen in den Schuss-MC selbst ein

[keulche]

hab ich jetzt alles so hibekommen, jetzt müßte ich nur noch jeder instanz eine funktion bewegen zuweisen.
Ich kann doch bestimmt in dem Movieclip "schuss" den ich instanziere mit konstruktoren, destruktoren bzw. methoden implementieren.

Also in "schuss" soll folgendes drinstehen:

... Konstruktor evtl _x=_root.ship1._x;
... Destruktor

und folgende methode:

function bewegen(){

this._x-=this._x;

}

hat da jemand ne ahnung wie ich das lösen könnte, problem ist halt, dass sich die instanz nur solange bewegt bis eine neue instanz erzeugt wird.
Irgendwie muß ich die Funktion doch ableiten können.

[the binary]

hier mal ein vorschlag..

ein symbol schuss erstellen und die klasse 'Schuss' zuweisen.

PHP-Code:

class Schuss
    extends MovieClip
{
    private var ix : Number = 0;
    private var iy : Number = 30;


    // public static var libID : String = "__Packages.Schuss";
    // private static var _isSymbolLinked : Boolean = Object.registerClass( libID, Schuss );

    public var speed : Number = 5;

    function Schuss()
    {
        initShoot();
        fly();
    }

    private function initShoot() : Void
    {
        this._x = ix;
        this._y = iy;
    }

    private function fly() : Void
    {
        this.onEnterFrame = function()
        {
            this._y -= speed;
        }
    }

    public function remove() : Void
    {
        this.removeMovieClip();
    }
} 


zum test.
in den ersten frame deiner hzl kommt dann dass...

PHP-Code:


onMouseDown = function()
{
    trigger();
}

onMouseUp = function()
{
    release();
}

function trigger()
{
    _root.onEnterFrame = mx.utils.Delegate.create( this, shoot );
}

function release()
{
    delete _root.onEnterFrame;
}

function shoot()
{
    _root.attachMovie('Schuss', 's', _root.getNextHighestDepth(), { ix:_root._xmouse, iy:_root._ymouse } );
} 


die remove-methode ist noch nicht implementiert...


gruss