attachMovie auf Maus-Ereignisse reagieren klappt nicht

[gisworks]

Hallo,

ich habe mir ein kleines Zeichnen-Flash zusammengestellt (siehe zip).
Im MC mappe wird bei onPress mittels createEmptyMovieClip der mc zeichnung angelegt und bis zum Doppelklick Punkte gezeichnet (attachMovie vertex usw.) und mit moveTo, lineTo verbunden.

Ich will aber ermöglichen, die Stützpunkte der Linie hinterher noch zu ändern.
Aber es will mir nicht gelingen, den Punkten (mc vertex) Ereignisfunktionen zuzuweisen:

var myVertex = _root.mappe.zeichnung.attachMovie("vertex", "vertex", gDepth, {_x: _root.fromX, _y: _root.fromY});
gDepth += 1;
_root.mappe.zeichnung.vertex.onRollOver=function() {
trace("huhu");
}

die Punkte reagieren nicht auf das mausereignis, z.B. RollOver

Ich habe mir schon viel actionscript angeschaut, komme aber nicht weiter.


Vielen Dank im Voraus

Stefan

[fraggle two]

hi,

mach mal so...

var myVertex = _root.mappe.zeichnung.attachMovie("vertex", "vertex", gDepth, {_x: _root.fromX, _y: _root.fromY});
gDepth += 1;
myVertex.onRollOver=function(){
trace("huhu");
} 

gruß
mike

[harego]

ersetzte mal nein Script mit diesem :

PHP-Code:

// mit Stift zeichnen 
var dragX = "";
//Koordinaten während dragStylus();
var dragY = "";
var firstPoint = true;
//initialisierung
var linePoints = new Array ();
//Array mit Arrays [x,y] der geklickten Punkte
var gDepth = 1;
//Tiefenvariable der verschiedenen Grafik-Elemente
_root.mappe.onPress = function () {
    //oder onRelease  
    //trace("onPress");
    _root.fromX = _root.mappe._xmouse;
    _root.fromY = _root.mappe._ymouse;
    //Prüfen, ob klickPoint identisch mit vorherigem (Doppelklick)
    if (linePoints.length > 1) {
        lastX = linePoints[linePoints.length - 1][0];
        lasty = linePoints[linePoints.length - 1][1];
        if (lastX == _root.fromX && lastY == _root.fromY) {
            //identisch: Doppelclick
            dropStylus ();
            return;
        }
    }
    linePoints.push ([_root.fromX, _root.fromY]);
    //klickPoint hinzufügen
    if (firstPoint == true) {
        var myZeichnung = _root.mappe.createEmptyMovieClip ("zeichnung", gDepth);
        gDepth += 1;
        firstPoint = false;
        //StartPunkt setzen
        mynode = myZeichnung.attachMovie ("node", "startPoint", gDepth);
        gDepth += 1;
        //set position for node
        myZeichnung.startPoint._x = _root.fromX;
        myZeichnung.startPoint._y = _root.fromY;
        //dragable stylus setzen        
        myStift = myZeichnung.attachMovie ("mcStylus", "mcStylus", gDepth);
        gDepth += 1;
        //set starting position for stylus
        myStift._x = _root.fromX;
        myStift._y = _root.fromY;
        dragStylus ();
        //drag function aufrufen
    }
    else {
        var myVertex = _root.mappe.zeichnung.attachMovie ("vertex", "vertex" + gDepth, gDepth, {_x:_root.fromX, _y:_root.fromY});
        _root.mappe.zeichnung["vertex" + gDepth].onRollOver = function () {
            trace ("huhu");
        };
        gDepth += 1;
    }
};
function dragStylus () {
    //starts dragging the stylus
    _root.mappe.zeichnung.mcStylus.startDrag (true, 0, 0, 200, 200);
    _root.mappe.zeichnung.mcStylus.onMouseMove = lineCalc;
}
function dropStylus () {
    delete _root.mappe.onPress;
    //drops the stylus
    _root.mappe.zeichnung.mcStylus.stopDrag ();
    //_root.mappe.zeichnung.mcStylus.onMouseMove = null;
    _root.mappe.zeichnung.mcStylus.removeMovieClip ();
    //stift entfernen
    _root.mappe.zeichnung.attachMovie ("node", "endPoint", gDepth - 1);
    _root.mappe.zeichnung.endPoint._x = _root.fromX;
    _root.mappe.zeichnung.endPoint._y = _root.fromY;
}
function lineCalc () {
    //calculates the coords of the drag point to 1 above/below min/max so it fits inside the window)
    if (_root.mappe.zeichnung.mcStylus._x > _root.mappe._width) {
        //wenn stylus außérhalb, dann dragX 1 pt innerhalb 
        dragX = _root.mappe._width - 1;
    }
    else {
        if (_root.mappe.zeichnung.mcStylus._x < 0) {
            dragX = 1;
        }
        else {
            dragX = _root.mappe.zeichnung.mcStylus._x;
        }
    }
    if (_root.mappe.zeichnung.mcStylus._y > _root.mappe._height) {
        dragY = _root.mappe._height - 1;
    }
    else {
        if (_root.mappe.zeichnung.mcStylus._y < 0) {
            dragY = 1;
        }
        else {
            dragY = _root.mappe.zeichnung.mcStylus._y;
        }
    }
    _root.mappe.zeichnung.clear ();
    _root.mappe.zeichnung.lineStyle (2, 0xFF0000);
    //color of rectangle outline
    //wenn mindestens zwei punkte in linePoints
    if (linePoints.length > 1) {
        //trace("linePoints > 1");
        //Startpunkt holen
        startX = linePoints[0][0];
        startY = linePoints[0][1];
        //bisherige Segmente zeichnen
        for (var i = 1; i < linePoints.length; i++) {
            nextX = linePoints[i][0];
            nextY = linePoints[i][1];
            drawLine (startX, startY, nextX, nextY);
            startX = nextX;
            //startpunkt für Folgesegment
            startY = nextY;
        }
    }
    drawLine (_root.fromX, _root.fromY, dragX, dragY);
    updateAfterEvent ();
}
//method for drawing the rectangle
function drawLine (x, y, xx, yy) {
    //trace(x+", "+y+", "+xx+", "+yy);
    // x, y = start point of line
    // xx, yy = end point of line
    _root.mappe.zeichnung.moveTo (x, y);
    _root.mappe.zeichnung.lineTo (xx, yy);
} 


[gisworks]

Herzlichsten Dank harego,

aber die Änderung in:

var myVertex = _root.mappe.zeichnung.attachMovie ("vertex", "vertex" + gDepth, gDepth, {_x:_root.fromX, _y:_root.fromY});
_root.mappe.zeichnung["vertex" + gDepth].onRollOver = function () {
trace ("huhu");
};
gDepth += 1;

allein wars wohl nicht.
Wo ist denn was geändert?

[harego]

Diese von dir genannten Zeilen und:

PHP-Code:

function dropStylus () {
    delete _root.mappe.onPress; <===