attach movie initObject frage....

[salazar]

hi ihrs.....
habe da mal ne frage.....
hatte es bisher so gemacht.... auf meiner bühne liegen vier mc´s mit jeweils dem folgenden script drauf:

onClipEvent(load){
_root.planet01X = this._x
_root.planet01Y = this._y
_root.planet01Xscale = this._xscale;
_root.planet01Yscale = this._yscale;
speed = 5
}
 
onClipEvent(enterFrame){
this._x += (_root.planet01X - this._x)/speed;
this._y += (_root.planet01Y - this._y)/speed;
this._xscale += (_root.planet01Xscale - this._xscale)/speed;
this._yscale += (_root.planet01Yscale - this._yscale)/speed;
} 

alles wunderbar soweit, aber jetzt will ich diese mc´s attachen!

das soll so geschehen.....:

for ( var i = 1; i < 4 + 1; i++ ){
    attachMovie("planet", "planet0"+i, i);
} 

wie muß nun das initObject aussehen damit ich das ganze as mit dem mc zusammen attachen kann??

thx & cya, sal

[beachmeat]

das im Onload würd ich ins initObjekt nehmen, denn onLoad funzt bei attach nadürlisch nich

var obj = {}
obj.wert = bla
var ref =attachMovie("planet", "planet0"+i, i,obj);
 
//das enterFrame dann so:
 
ref.onEnterFrame = function()
{
 // aktion
} 

[HAY]

hi
so in etwa. du must die mc aber noch positionieren.

for ( var i = 1; i < 4 + 1; i++ ){
        mc= this.attachMovie("planet", "planet0"+i, i,(_x:300,_y:300,_xscale:100,_yscale:100,speed:5);
        _root["planet0"+i+"X"] = mc._x
        _root["planet0"+i+"Y"]= mc._y
        _root["planet0"+i+"Xscale"] = mc._xscale;
        _root["planet0"+i+"Yscale"] = mc._yscale;
                mc.i=i
        mc.onEnterFrame = function() {
        this._x += (_root["planet0"+this.i+"X"] - this._x)/speed;
        this._y += (_root["planet0"+this.i+"Y"]- this._y)/speed;
        this._xscale += (_root["planet0"+this.i+"Xscale"]- this._xscale)/speed;
        this._yscale += (_root["planet0"+this.i+"Yscale"]- this._yscale)/speed;
}
} 

[edit] mir hats hier einiges verrissen

[georgexp]

hi,

ich würd das so machen :

for ( var i = 1; i < 4 + 1; i++ ){
    neuerPlanet="planet0"+String(i)
    this.attachMovie("planet", neuerPlanet, i,{_x:300,_y:300,_xscale:100,_yscale:100,speed:5})
    this[neuerPlanet].onEnterFrame=function() {
        this._x += (this.destX - this._x) / this.speed
        this._y += (this.destY - this._y) / this.speed
        this._xscale += (this.Xscale - this._xscale)/speed
        this._yscale += (this.Yscale - this._yscale)/speed
    }
} 

untested. sollte aber funktionieren.

[edit]
Beach, schöne Lösung .

[salazar]

wow, geilo! vielen dank schonmal an euch... werds gleich mal antesten....

@georgexp:
sieht gut aus.... will aber diese funktion später attachen... also zunächst sollen die mc´s attached werden und dann zu einem späteren zeitpunkt will ich dann auf die "funktion" zugreifen....

wie rufe ich die dann später wieder auf? so?:

this[neuerPlanet].onEnterFrame=function(_x:300,_y:300,_xscale:100,_yscale:100,speed:5) { 

thx & cya, sal

[georgexp]

... will aber diese funktion später attachen...

Wenn du damit meinst das du diese zu einem späterem Zeitpunkt
ausführen möchtest,

Variable vorschalten,

for ( var i = 1; i < 4 + 1; i++ ){
        neuerPlanet="planet0"+String(i)
        this.attachMovie("planet", neuerPlanet,  i,{_x:300,_y:300,_xscale:100,_yscale:100,speed:5, alive:false})
        
        this[neuerPlanet].onEnterFrame=function() {
                if (this.alive) {
                    this._x += (this.destX - this._x) / this.speed
                    this._y += (this.destY - this._y) / this.speed
                    this._xscale += (this.Xscale - this._xscale)/speed
                    this._yscale += (this.Yscale - this._yscale)/speed
                 }
      }
} 

Wenn es dann soweit ist, schaltest du "alive" in den mc's auf true.


Du kannst aber auch den mc die Funktion später zuweissen.
Das würde so aussehen :

planet01.onEnterFrame=function() {
                    this._x += (this.destX - this._x) / this.speed
                    this._y += (this.destY - this._y) / this.speed
                    this._xscale += (this.Xscale - this._xscale)/this.speed
                    this._yscale += (this.Yscale - this._yscale)/this.speed
} 

hoffe das hilft weiter....

[salazar]

ich komm der sache auf jedenfall schon näher....
vielen dank soweit für deine mühe.. werde jetzt einfach mal drauflos scripten und schauen wie es klappt

melde mich dann nochmals

thx & cya, sal

[HAY]

hi
ich nochmal ich vermisse die initialiesirung der variablen auf _root.

[salazar]

ich auch, aber das kann man ja vorweg machen bzw initialisieren....

also wie bereits gehabt:
ziel ist es z.B. 4 movies zu attachen an feste positionen, welche ich dann aber später noch mit dem vorgestellten as schön "smooth" bewegen will...


thx & cya, sal

[georgexp]

HAY,

Wozu ? Ich fand sie auf Mc Ebene sinnvoller.

[HAY]

ich glaube so wäre es dann sinnvoll

MovieClip.prototype.setzen=function(){
        _root[this._name+"X"] =this._x
        _root[this._name+"Y"]= this._y
        _root[this._name+"Xscale"] =this._xscale;
        _root[this._name+"Yscale"] =this._yscale;
                this.onEnterFrame = function() {
                this._x += (_root[this._name+"X"]  - this._x)/this.speed;
          this._y += (_root[this._name+"Y"] - this._y)/this.speed;
                this._xscale += (_root[this._name+"Xscale"]- this._xscale)/this.speed;
                  this._yscale += (_root[this._name+"Yscale"]- this._yscale)/this.speed;
}
}
for ( var i = 1; i < 5; i++ ){
        _root.attachMovie("planet", "planet0"+i, i,{_x:30*i,_y:30*i,_xscale:100,_yscale:100,speed:6})
        _root["planet0"+i].setzen()
}
// das ist nur der Test
_root.planet02X=400 

[edit] hatte noch 2_root vergessen

[salazar]

@HAY: das sieht sehr sehr gut aus! bins gerade mal am integrieren

ich melde mich...

thx & cya, sal

[salazar]

müßte es nicht

this["planet0"+i].setzen() 

statt

_root["planet0"+i].setzen() 

lauten?

thx & cya, sal

[HAY]

hi
besser ganz auf _root verzichten (georgexp )

MovieClip.prototype.setzen=function(){
        this.X=this._x
        this.Y= this._y
        this.Xscale=this._xscale;
        this.Yscale =this._yscale;
                this.onEnterFrame = function() {
                this._x += (this.X - this._x)/this.speed;
          this._y += (this.Y- this._y)/this.speed;
                this._xscale += (this.Xscale- this._xscale)/this.speed;
                  this._yscale += (this.Yscale- this._yscale)/this.speed;
                }
}
for ( var i = 1; i < 5; i++ ){
        this.attachMovie("planet", "planet0"+i, i,{_x:30*i,_y:30*i,_xscale:100,_yscale:100,speed:6})
        this["planet0"+i].setzen()
}
 
planet02.X=400
planet02.Xscale=10 

[HAY]

hi salasr
so ist auch nicht schlecht.

MovieClip.prototype.setzen=function(X,Y,Xscale,Yscale,speed){
                this.onEnterFrame = function() {
                this._x += (X - this._x)/speed;
          this._y += (Y- this._y)/speed;
                this._xscale += (Xscale- this._xscale)/speed;
                  this._yscale += (Yscale- this._yscale)/speed;
}
}
for ( var i = 1; i < 5; i++ ){
        this.attachMovie("planet", "planet0"+i, i,{_x:0,_y:0,_xscale:100,_yscale:100})
}
planet01.setzen(400,400,10,10,6)
planet02.setzen(400,300,30,30,10)
planet03.setzen(300,400,40,40,15)
planet04.setzen(200,200,50,50,20)