Alpha-Wert von Instanz animieren

[Skilo]

Hallo, ich habe eine Frage, zu der ich nichts direkt gefunden haben, auch wenns vielleich schon irgendwo steht...

(Wie) kann ich über AS den Alpha-Wert einer Instanz animieren?

Ich habe einige Buttons, bei deren RollOver verschiedene MCs eingeblendet und beim RollOut wieder ausgeblendet werden sollen. Momentan mache ich das über die einfache Funktion

on (rollOver) {
    x1._visible = true;
}
on (rollOut) {
    x1._visible = false;
} 

mit ensprechend verschiedenen Namen für die Buttons.

Das sieht allerdings nicht besonders gut aus, deshalb würde ich z.B. gerne über 4 Frames die Instanz "x1" ein bzw. wieder ausblenden.

Kann mir jemand einen Tipp geben? Danke!

[Loré]

Hi, ganz einfach:

var id;
_root.mc1.onRollOver = function (){
 _root.id = setInterval(fadeIn, 10);
};
 
_root.mc1.onRollOut = function (){
 _root.id = setInterval(fadeOut, 10);
};
 
function fadeIn (){
 if(_root.mc1.mc11._alpha == 100){
  clearInterval(_root.id);
 }else{
  _root.mc1.mc11._alpha += 10;
 }
}
 
function fadeOut (){
 if(_root.mc1.mc11._alpha == 0){
  clearInterval(_root.id);
 }else{
  _root.mc1.mc11._alpha -= 10;
 }
} 

Bei bedarf erweitere einfach die _alpha-Setzungen und die Werte!
Lore

[Flashkonsole]

mit mc._alpha = 100
kannst du den alphawert von 0-100 setzen.

um das zu animieren gibt es mehrere Möglichkeiten:
- onEnterFrame -> immer +1 (ist vielleicht zu schnell)
- setInterval() dort kannst du das Interval selbst bestimmen
- oder ganz ohne AS einfach dem Clip eine TWeen zuweisen per script abspielen

[Skilo]

Hallo und danke für die Antworten.

@Loré: Wo muss denn das Script hinein? In die Hauptzeitleiste?
Und was für Instanzen sind "mc1" bzw. "mc11"?

[Der Frager]

Das Script gehört in die Hauptzeitleiste. Allerdings ist es (gerade bei _alpha) nicht sehr empfehlenswert, mit == 100 und == 0 zu arbeiten. Hier noch ein anderes Beispiel:

this.x1._alpha = 0
this.dein_mc.onRollOver = function() {
    fade(x1, 10);
};
this.dein_mc.onRollOut = this.dein_mc.onDragOut = function() {
    fade(x1, -10);
};
//
_global.fade = function(mc, nr) {
    mc.onEnterFrame = function() {
        this._alpha += nr;
        if (this._alpha>100 || this._alpha<0) {
            delete this.onEnterFrame;
        }
    };
}; 

[Skilo]

Super, genau das hatte ich gesucht. Vielen Dank!