aktiver button soll immer unten stehen

[mojojojo]

hallo zusammen.

ich schlag mich jetzt schon paar tage mit folgendem problem rum:

ich hab ein vertikal angeordnetes menü. wenn man jetzt auf einen button klickt, soll dieser nach unten an die letzte stelle fahren und größer werden.
klickt man einen anderen button an, soll der vorher aktive button wieder auf ursprüngliche größe schrumpfen (und halt der jetzt aktive button nach unten rutschen). so..hm..wie ne kette..oder so.

ich such seit tagen im web (weil ich meine, sowas schonmal vor monaten gelesen zu haben) aber find nix - nicht mal n bisschen was.

ich hatte mal angedacht ein script für ein panorama in die richtung zu verändern...aber klappte nicht (bin leider - noch - nicht so sattelfest in richtiger as-programmierung).

wäre super, wenn mir hier jemand weiterhelfen könnte.

[Der Frager]

Hallo und willkommen im Forum!

Wie sieht denn dein bisheriges Script bzw. deine fla aus?

[mojojojo]

hallo. danke.

das was ich versucht habe (um-) zu scripten, war das panorama script. und das hat vorne u hinten nicht hingehauen - habs dann sehr frustriert einfach nicht gespeichert. aber ich denke, dass war sowieso eine idee ohne lösung.

eine neue fla hab ich noch nicht angelegt weil mir jegliche idee fehlt.

dinge mit as irgendwo hin zu schieben raff ich ja noch - aber die buttons, die unten verschwinden, müssen dann oben ja wieder auftauchen (deshalb hatte ich zuerst ans pano-script gedacht). ganz davon zu schweigen, dass die buttons ja einen aktiv-zustand bis zum nächsten klick halten müssen.

das wäre mein script für ne bewegung der buttons- fehlt noch ne variable für die mcs, aber lässt sich darauf überhaupt aufbauen?

PHP-Code:

function slideMenu() {
    this._x += (zielX - this._x) / 8;
    this._y += (zielY - this._y) / 8;
}

mc.onEnterFrame = slideMenu;

btn1.onRelease = function() {
    zielX = 0;
    zielY = 20;
};
btn2.onRelease = function() {
    zielX = 0;
    zielY = 100;
}; 


[Der Frager]

Hi!
Schnell mal was getippelt. Ich wette, das sieht jetzt nicht so aus, wie du es haben willst, aber damit solltest du irgendwie weiterkommen...

PHP-Code:

MovieClip.prototype.moveMe = function(zielY, scale) {
    this.onEnterFrame = function() {
        Math.round(this._y) != zielY ? this._y += (zielY-this._y)/5 : (delete this.onEnterFrame, this._y=zielY, this.scaleMe(scale));
    };
};
//
MovieClip.prototype.scaleMe = function(size) {
    this.onEnterFrame = function() {
        Math.round(this._xscale) != size ? this._xscale=this._yscale += (size-this._xscale)/5 : (delete this.onEnterFrame, this._xsclale=this._yscale=size);
    };
};
for (var x = 0; x<4; x++) {
    var btn = this.attachMovie("btn", "btn"+x, x, {_y:35*x});
    btn.txt.text = "button "+x;
    btn.y = btn._y;
    btn.onRelease = function() {
        this.moveMe(150, 150);
        if (_root.lastone != this) {
            _root.lastone.moveMe(_root.lastone.y, 100);
        }
        _root.lastone = this;
    };
} 


[mojojojo]

cool. danke erstmal!

hab n paar sachen verstanden - aber natürlich nicht alles.

- wo wird festgelegt, wieviel abstand der button, der nach unten läuft vom letzten button hat (an dem orientiert sich das ja..oder?!)

- das funktioniert auch, wenn der mc nicht attached wird und ich die buttons "eigenhändig" auf der bühne plaziere? klappte im ersten versuch nicht aber dann schau ich mal weiter.

- jetzt zu der frage, die mir am peinlichsten ist: wie hilft mir das weiter? ich seh nicht, wo (vor allem wie) ich den anderen buttons sagen soll, dass sie sich alle (ketten-like) bewegen soll.

danke für die fla übrigens - aber mein flash öffnet nix, was ich downgeloadet hab. (weis nicht warum, aber geht ja auch so)

[Der Frager]

Nö, da orientiert sich momentan nix an der Gesamthöhe aller Buttons. Das hier

PHP-Code:

this.moveMe(150, 150); 


sagt halt beweg dich zur Y-Position 150 und vergrößere dich um 50%. "Kettenlike?" was meinste damit? Vielleicht sowas in der Art:

PHP-Code:

var tl = this;
var abst = 5;
var oEF = 0;
var speed = 5
var arr = ["links", "über uns", "kontakt", "impressum", "bla"];
var anz = arr.length;
for (var x = 0; x<anz; x++) {
    var btn = tl.attachMovie("btn", "btn"+x, x, {_y:(btn._height*x)+abst*x});
    btn.id = x;
    btn.y = btn._y;
    btn.txt.text = arr[x];
    btn.onRollOver = function() {
        oEF += 1;
        this.onEnterFrame = function() {
            if (this._yscale<150) {
                this._yscale = this._xscale += speed;
                for (var x = 0; x<anz; x++) {
                    if (x<this.id) {
                        tl["btn"+x]._y = tl["btn"+(x+1)]._y-(tl["btn"+(x+1)]._height/2)-abst-tl["btn"+x]._height/2;
                    } else if (x>this.id) {
                        tl["btn"+x]._y = tl["btn"+(x-1)]._y+(tl["btn"+(x-1)]._height/2)+abst+tl["btn"+x]._height/2;
                    }
                }
            } else {
                delete this.onEnterFrame;
            }
        };
    };
    btn.onRollOut = btn.onDragOut=function () {
        oEF -= 1;
        this.onEnterFrame = function() {
            if (this._yscale>100) {
                this._yscale = this._xscale -= speed;
                for (var x = 0; x<anz; x++) {
                    if (x<this.id) {
                        tl["btn"+x]._y = tl["btn"+(x+1)]._y-(tl["btn"+(x+1)]._height/2)-abst-tl["btn"+x]._height/2;
                    } else if (x>this.id) {
                        tl["btn"+x]._y = tl["btn"+(x-1)]._y+(tl["btn"+(x-1)]._height/2)+abst+tl["btn"+x]._height/2;
                    }
                }
            } else {
                delete this.onEnterFrame;
                if (oEF == 0) {
                    for (var x = 0; x<anz; x++) {
                        tl["btn"+x]._y = tl["btn"+x].y;
                    }
                }
            }
        };
    };
    btn.onRelease = function() {
        trace(this.txt.text);
    };
} 


[mojojojo]

oh

this.moveMe(150, 150);

*peinlich*

zum script oben: nee - aber is cool. mit "kette" mein ich..hm..so hier:

BUTTON 1
BUTTON 2
BUTTON 3
BUTTON 4

nach klick auf BUTTON 2 bewegt der sich dann auf position von BUTTON 4.
BUTTON 1 bleibt dabei immer über 2 und weil 3 u 4 quasi unten "rausgedrückt" werden kommen die dann oben wieder rein. (kann man das nachvollziehen?)

BUTTON 3
BUTTON 4
BUTTON 1
BUTTON 2

wegen dem "unten-raus-und-oben-wieder-rein" war mein erster gedanke ja panorama-scroll-script. aber das was ich hab, reagiert abhängig von der mouse position.

weist du ungefähr was ich meine? isses sehr kompliziert das zu realisieren und nervt das sehr, wenn ich dann 1000 fragen hab - dann setz ichs nochmal auf die reservebank, bis ich mehr plan vom scripten hab.

[Der Frager]

Aha... Da könntest du auch mal nach "yugop" suchen. Sind zwar meistens Fotos, die da dann veschoben werden, aber das könntest du ja anpassen. So wirklich schwierig ist's nicht, Plan von AS sollte man allerdings schon haben .

[mojojojo]

ich kenn das yugop-menü aber das ist nicht das, was ich vorhab. (oder geht das script in die selbe richtung?)

abgesehen davon steht in den 500 post zu yugop in bestimmt 400

such mal nach yugop

(hab ich vor dem eröffnen dieses themas auch schon nach gesucht, weils menü erst anders aussehen sollte)

hab hier schnell n beispiel swf mit tweens gebastelt: [ATTACH]beispiel[/ATTACH]

[newton]

Háb mir dein Beispiel mal angesehen.
Würde kurzerhand folgende Lösung vorschlagen.

PHP-Code:

Algorithmus:
  1. Mit Buttonklick merken welcher Button gedrückt wurde
  2. Alle (vier) Buttons um eine Position nach unten schieben
  3. Abfrage ob der gedrückte an gewünschter Stelle ist
  3.1. Wenn nicht, nach 4. wieder zu 2.
  3.2. Wenn ja, nach 4. stoppen
  4. letzten Button ganz nach oben schieben 


Schon etwas aufwendig, aber von 'Der Frager' hast ja schon mal die Grundfunktionen auf welche du aufbauen kannst.

[RustyCake]

Nette Algorithmus_Idea!!!
Wenn Du einen Plan hättest, könntest Du auch erkennen das das script von "der Frager" nicht des wirklich richtige für diesen Job ist!!
@ "der Frager" was nicht heißen soll das des Script nicht Geil ist
Einen kurzen "Dirty Hack" von mir, man müßte einen Listener verwenden ums sauber zu scripten, jetzt verschieben sich die ganzen Buttons noch ein bisschen!
Aber so als Ansatz wirds schon gehen!!

PHP-Code:

var btn_xPos = 100;
var btn_yPos = 50;
var btn_hoehe = main_mc._height;
var anzahl_btn = 4;
_global.Mct;
for (var i = 0; i<anzahl_btn; i++) {
    var m = this.main_mc.duplicateMovieClip("dub_mc"+i, 100+i, {_x:btn_xPos, _y:(btn_hoehe*i)+btn_yPos});
    m.texter_txt.text = m._name;
    m.onPress = function() {
        if (this._y != 140) {
            _global.Mct = this;
            forMove();
        }
    };
}
function forMove() {
    for (var j = 0; j<anzahl_btn; j++) {
        this["dub_mc"+j].moverTo();
    }
}
MovieClip.prototype.moverTo = function() {
    this.onEnterFrame = function() {
        this._y += 1;
        if (Math.ceil(Mct._y) == 140) {// hier war ich zu Faul mit Variablen zu arbeiten
            delete this.onEnterFrame;
        }
        if (this._y>=btn_yPos+(this._height*anzahl_btn)) {
            this._y = btn_yPos;
        }
    };
}; 


[Der Frager]

So, hier dann nochmal so ein Proll-Menü . Funzt aber nur mit AS 2.0...

PHP-Code:

var tl = this;
tl.setMask(mask);
function tween(mc, ziel) {
    new mx.transitions.Tween(mc, "_y", mx.transitions.easing.Bounce.easeOut, mc._y, ziel, 10);
}
for (var x = 0; x<4; x++) {
    var btn = this.attachMovie("btn", "btn"+x, x, {_y:35*x});
    btn.txt.text = "button "+x;
    btn.pos = x;
    btn.onRelease = function() {
        if (!running) {
            _global.running = true;
            _global.clicked = this.pos;
            for (var x = 0; x<4; x++) {
                var btn = tl["btn"+x];
                if (btn.pos>clicked) {
                    tween(btn, 170);
                }
            }
            iv = setInterval(function () {
                clearInterval(iv);
                for (var x = 0; x<4; x++) {
                    var btn = tl["btn"+x];
                    btn.pos>clicked ? (btn.pos -= clicked+1, btn._y=-40) : (btn.pos += 3-clicked, tween(btn, btn.pos*35));
                }
            }, 1000);
            iv1 = setInterval(function () {
                clearInterval(iv1);
                for (var x = 0; x<4; x++) {
                    var btn = tl["btn"+x];
                    btn._y == -40 ? tween(btn, btn.pos*35) : 0;
                }
                _global.running = false
            }, 2000);
        }
    };
} 


[mojojojo]

hallo.

danke für eure scripts (u die mühe)! as 2.0 jeht leider nicht, weil ich mx hab. (wie kann man das auch abwärts konvertieren?)

@ rustyCake

man müßte einen Listener verwenden

...blöde frage aber - wie u welchen?

in allen scripten wird ein mc aus der lib geholt, geklont und per as platziert. funktionieren die scripte nur so oder kann man die auch auf "per hand" auf die bühne gelegte mcs anwenden?

[Der Frager]

So, hier mal als MX. Ist zwar der "Bounce"-Effekt wech, aber auch egal... Das sollte, wenn du den Buttons die richtigen Instanznamen gibst, auch mit von Hand auf der Bühne platzierten gehen. Wie gesagt sind das ja nur Beispiele, wie man's machen könnte...

PHP-Code:

var tl = this;
tl.setMask(mask);
function tween(mc, ziel) {
    mc.onEnterFrame = function() {
        Math.round(this._y) != ziel ? this._y += (ziel-this._y)/2 : (delete this.onEnterFrame, this._y=ziel);
    };
}
for (var x = 0; x<4; x++) {
    var btn = this.attachMovie("btn", "btn"+x, x, {_y:35*x});
    btn.txt.text = "button "+x;
    btn.pos = x;
    btn.onRelease = function() {
        if (!running) {
            _global.running = true;
            _global.clicked = this.pos;
            for (var x = 0; x<4; x++) {
                var btn = tl["btn"+x];
                if (btn.pos>clicked) {
                    tween(btn, 170);
                }
            }
            iv = setInterval(function () { clearInterval(iv);for (var x = 0; x<4; x++) {var btn = tl["btn"+x];btn.pos>clicked ? (btn.pos -= clicked+1, btn._y=-40) : (btn.pos += 3-clicked, tween(btn, btn.pos*35));}}, 1000);
            iv1 = setInterval(function () { clearInterval(iv1);for (var x = 0; x<4; x++) {var btn = tl["btn"+x];btn._y == -40 ? tween(btn, btn.pos*35) : 0;}_global.running = false;}, 2000);
        }
    };
} 


[mojojojo]

schau ich mir heute abend in ruhe an und hab dann morgen bestimmt noch paar fragen. (...zum besseren verständnis vom script..weil mojoauchwilllernen!)

also danke nochmal jungs!