adressierung falsch?!

[suicidegirl]

hi,

bastele hier an einer kleinen diashow. es soll bei klick auf das bild, dieses ausgeblendet werden. leider bekomme ich die adressierung der einzelnen bilder nicht hin. wenn ich mir den namen ausgeben lasse, steht dort immer nur 0.0, warum auch immer?! kann jmd. einen tipp geben? script:

PHP-Code:

/* alpha func */
function alphalize(ziel) {
    var myAlpha:Alpha = new Alpha(ziel);
    myAlpha.animationStyle(2500, Sine.easeInOut);
    myAlpha.run(0);
}
/* meins */
var tempxml;
var fehler;
var pfad;
var arrPics = new Array();
function initPics(obj, clip, tiefe, bildanzahl, bildnummer, bildOrdner) {
    for (var i = 0; i<=tempxml.length; i++) {
        createEmptyMovieClip(obj+i, tiefe-i);
        arrPics.push(this[obj+i][clip+i]);
        this[obj+i].attachMovie(clip, clip+i, i);
        pfad = bildOrdner+tempxml[i-1].attributes.picGross;
        this[obj+i][clip+i].mc.loadMovie(pfad);
        this[obj+i][clip+i].onRelease = function() {
            alphalize(arrPics[i-1]);
        };
        this[obj+i][clip+i].bildname = this[obj+i];
    }
}
datei = "/cms/serv/xml.php/"+_root.kat1_raw+"/"+_root.kat2_raw+"/"+_root.ueberschrift;
meinXML = new XML();
meinXML.ignoreWhite = true;
meinXML.load(datei);
meinXML.onLoad = function(status) {
    if (status) {
        tempxml = meinXML.firstChild.childNodes;
        initPics("container", "bild", 100, anzahl, 1, "/cms/pix/");
        delete meinXML;
        fehler = "";
    } else {
        fehler = "Leider keine Bilder vorhanden.";
    }
}; 


wäre sehr zu dank verpflichtet.

[hgseib]

ohne fla kann man nichts testen.

for (var i = 0; i<=tempxml.length; i++) {
	var obji=this.createEmptyMovieClip(obj+i, tiefe-i);
	var clipi=obji.attachMovie(clip, clip, 1); // i ist hier unnötig, es gibt je obji nur einen eintrag
	clipi.nr = arrPics.push(clipi);
	var pfad = bildOrdner+tempxml[i-1].attributes.picGross;
	clipi.mc.loadMovie(pfad);
	clipi.onRelease = function() {
		alphalize(arrPics[this.nr]); // bis onRelease geklickt wird gibt es kein i mehr
	};
	clipi.bildname = obji; // hier weisst du ein objekt zu und keinen namen!?
}

"..wäre sehr zu dank verpflichtet.."
ok, putzt du mir jetzt meine schuhe oder was?

[suicidegirl]

weiss nicht, obs das bringt, aber anbei die fla... habe alles ein wenig umgestrickt und eine diashow hier aus dem forum genommen. der code sieht jetzt so aus:

PHP-Code:

import de.sonntagsfarben.animation.SlideShow;
var tempxml;
var fehler;
var ordner = "http://www.domain.de/demo2/bilder/";
var pfad = "http://www.domain.de/cms/serv/xml.php"+_root.parameter;
var aBilder:Array = new Array();
function initPics() {
    for (var i = 1; i<=tempxml.length; i++) {
        var pic = tempxml[i-1].attributes.picGross;
        _root.aBilder.push(pic);
        fehler += pic; // ergibt die richtigen bilder
        fehler += _root.aBilder[i]; // bilder nicht ins array eingefügt!!!
        fehler += "\n";
    }
}
meinXML = new XML();
meinXML.ignoreWhite = true;
meinXML.load(pfad);
meinXML.onLoad = function(status) {
    if (status) {
        tempxml = meinXML.firstChild.childNodes;
        fehler = "";
        initPics();
        delete meinXML;
    } else {
        fehler = "Leider keine Bilder vorhanden.";
    }
};
var slideShow:SlideShow = new SlideShow(mcHolder, _root.aBilder, 4, ordner, null);
stop(); 


irgendwie füllt er das aray nicht. warum denn nur?!

[hgseib]

"..weiss nicht, obs das bringt, aber anbei die fla.."
ohne das XML ganz gewiss nicht.

"..irgendwie füllt er das aray nicht.."
mit was sollte er es denn füllen?

und deine slideShow gehört wohl in den "if (status)"-block.


bau ein paar trace-befehle in deinen script ein, um zu prüfen ob in den variablen das drinn ist, was du dir erhoffst.

und benutze mal den debugger. damit kannst du dein programm schritt für schritt abarbeiten. siehe meine signatur.

[suicidegirl]

das initialisieren der slideshow erfolgte einfach an der falschen stelle. konnte nicht klappen.

PHP-Code:

import de.sonntagsfarben.animation.SlideShow;
var tempxml;
var fehler;
var ordner = "http://www.domain.de/demo2/bilder/";
var pfad = "http://www.domain.de/cms/serv/xml.php"+_root.parameter;
var aBilder:Array = new Array();
function initPics() {
    for (var i = 1; i<=tempxml.length; i++) {
        var pic = tempxml[i-1].attributes.picGross;
        _root.aBilder.push(pic);
    }
    var slideShow:SlideShow = new SlideShow(mcHolder, _root.aBilder, 4, ordner, null);
}
meinXML = new XML();
meinXML.ignoreWhite = true;
meinXML.load(pfad);
meinXML.onLoad = function(status) {
    if (status) {
        tempxml = meinXML.firstChild.childNodes;
        fehler = "";
        initPics();
        delete meinXML;
    } else {
        fehler = "Leider keine Bilder vorhanden.";
    }
};
stop();