_root gegen _parent tauschen - geht nicht !

[PeterK]

Hallo,
ich habe einen Scroller auf der Hauptleiste und das funktioniert mit "_root" prächtig.
Jetzt habe ich den Scroller aber in einen mc gesteckt und wollte den Befehl "_root" gegen "_parent" ersetzen, damit man nicht immer auf die Pfade achten muss.

Leider funztz das überhaupt nicht.

Aber wenn ich "_root.MeinMC" benutze geht es auch nicht mehr... Bitte um Hilfe..

Anbei die fla zur Erklärung..

Danke

[Der Frager]

Hi!

_root ist nicht immer automatisch auch _parent...

[psyk]

Nimm mal alle Skripte raus und leg das Folgende in den Hauptzeitleiste.

PHP-Code:

var dragged = false;
var slider = this.meinmc.scrollbar.slider;
var initY =    slider._y;
var bar = this.meinmc.scrollbar.bar;
var tf = this.meinmc.tf
slider.onEnterFrame = function()
{
    if (!dragged)
    {
        this._y = (tf.scroll*(initY+bar._height-this._height))/tf.maxscroll;
        delete this.onEnterFrame;
    } else
    {
        tf.scroll = Math.round((this._y*tf.maxscroll)/(initY+bar._height-this._height));
    }
};
slider.onPress = function()
{
    this.startDrag(false, this._x, bar._y, this._x, bar._y+bar._height-this._height);
    dragged = true;
};
slider.onRelease = slider.onReleaseOutside=function ()
{
    stopDrag();
    dragged = false;
}; 


Edit:
Damn: Der Frager wieder! Hallöchen

[Der Frager]

Zitat von psyk

Nimm mal alle Skripte raus und leg das Folgende in den Hauptzeitleiste.

Angeber . Trotzdem Tach .

edit: Dafür habe ich nur die Pfade geändert - gibt's jetzt halt 2 Vorschläge.

edit2: Man könnte bei dir allerdings auch das onEnterFrame mal löschen, wenn's nicht mehr gebraucht wird. Also onPress() starten und onRelease() deleten.

[psyk]

Ok, auf Wunsch eines Einzelnen.

Aber hier stand ja eigentlich nix von optimieren.

[Der Frager]

Zitat von psyk

Ok, auf Wunsch eines Einzelnen.

Aber hier stand ja eigentlich nix von optimieren.

Jetzt hast du's aber zerballert (und alles meine Schuld)...

Meinte das eher so hier:

PHP-Code:

lv = new LoadVars();
lv.onData = function(was) {
    tf.text = was;
};
//
var slider = this.meinmc.scrollbar.slider;
var initY = slider._y;
var bar = this.meinmc.scrollbar.bar;
var tf = this.meinmc.tf;
//
slider.onPress = function() {
    this.startDrag(false, this._x, bar._y, this._x, bar._y+bar._height-this._height);
    this.onEnterFrame = function() {
        tf.scroll = Math.round((this._y*tf.maxscroll)/(initY+bar._height-this._height));
    };
};
slider.onRelease = slider.onReleaseOutside=function () {
    stopDrag();
    delete this.onEnterFrame
};
//
lv.load("News.txt"); 


[psyk]

Schön.

Bin mal wieder nicht bei der Sache.

und um es noch eins weiter zu treiben kicken wir mal das oEF.

PHP-Code:

lv = new LoadVars();
lv.onData = function(was) {
    tf.text = was;
};
//
var slider = this.meinmc.scrollbar.slider;
var initY = slider._y;
var bar = this.meinmc.scrollbar.bar;
var tf = this.meinmc.tf;
//
slider.onPress = function() {
    this.startDrag(false, this._x, bar._y, this._x, bar._y+bar._height-this._height);
    this.onMouseMove = function() {
        tf.scroll = Math.round((this._y*tf.maxscroll)/(initY+bar._height-this._height));
    };
};
slider.onRelease = slider.onReleaseOutside=function () {
    stopDrag();
    delete this.onMouseMove;
};
//
lv.load("News.txt"); 


[Der Frager]

onMouseMove() frisst in der Regel allerdings mehr Performance.

Nu ist's aber auch gut hier...

[PeterK]

Also ich bin .. überwältigt.. begeistert.. entzückt...

IHR SEID KLASSE....

Vielen Dank..

PS: Welche Version ist die Beste??? Grübel... Alle Wege führen nach ROM..