14 MCs, die sich per AS zu einer bestimmten Positon bewegen sollen!

[deskounlmtd]

Hi Leutz,
ich habe in meiner FLA 14 Ebenen, in denen jeweils ein MC liegt.
Diese habe ich links angeordnet zunächst. (Liegen alle auf X-95.0 Y10.0)

Nun sollen die MCs automatisch eine bestimmte Position einnehmen, (zunächst) mit einer einfachen, geraden Bewegung*.
thumb1 soll auf Position X5.0 Y10.0 gehen, thumb2 auf X75.0 Y10.0, thumb3 auf X145.0 Y10.0 usw. ...
Also der X-Wert wird von MC zu MC um 70 erhöht.

Wie gehe ich im AS-Dschungel vor?

*wenn das steht, würde ich aus der geraden Bewegung gerne eine abbremsende machen

edit: Natürlich könnte ich das ganz einfach mit einem Bewegungstween machen, aber ich würde das diesmal saugerne mit AS machen. Sonst bleibe ich ja ewig bei Bewegungstweens. T_T

[janoshnosh]

nun, eine bewegung machst du am besten mit einem oEF-event, einem onEnterFrame:

var ziel:Number = 100;
dein_mc.onEnterFrame = function () {
this._x += 1;
if (this._x >= ziel) delete this.onEnterFrame;
} 

eine abbremsende bewgung geht mit diesem kleinen trick:

var ziel = 100;
dein_mc.onEnterFrame = function () {
var fac:Number = Math.ceil((ziel - this._x) / 6);
this._x += fac;
if (this._x == ziel) delete this.onEnterFrame;
} 

das kannst du in einer for-schleife auch auf 14 mc's anwenden, seien diese hier einmal von dein_mc0 bis dein_mc13 benannt (bei einem solchen vorhaben immer von anfang an mit der null als ersten index anfangen!):

var anzahl:Number = 14;
for (var i = 0; i < anzahl; i++) {
var dein_mc:MovieClip = _root['dein_mc'+i];
var ziel:Number = 5 + i*70;
dein_mc.onEnterFrame = function () {
//...der code von weiter oben
}
} 

[den code habe ich mit absicht in [as] geschrieben, damit man ihn - hoffentlich bald wieder - dann in der richtigen formatierung lesen kann, für jetzt erstmal in flash einfügen, um ihn zu lesen.]

in dem stil würde ich das machen.

gruß janosch

[cirox]

Hi!

Also ich würde es über die onClipEvent(enterFrame) Methode der MCs machen.
Da kannst ja dann einfach einzeln die _x und _y werte setzen. Musst halt innendrin immer wieder abfragen, wie die "ist-position" des MCs und die "soll-position" ist. und dann eben so lange erhöhen (oder verringern), bis sie gleich sind.

ungefähr so:

onClipEvent(enterFrame)
{
     if(myMc._x<sollPosX)
     {
           myMc._x++;
     }
     if(myMc._x>sollPosX)
     {
           myMc._x--;
     }
     if(myMc._y<sollPosY)
     {
           myMc._y++;
     }
     if(myMc._y>sollPosY)
     {
           myMc._y--;
     }
}
usw...

wäre eine Lösung, sicher nicht die schönste, aber die funktioniert.




@janosch: Sorry, wollte dir nicht dazwischen pfuschen, haben wohl gleichzeitig geantwortet.
Deine Variante ist defnitiv die sauberere. =)

[deskounlmtd]

Egal, dann kriege ich halt 2 Versionen zu sehen - umso besser!
Danke erstmal Jungs!

[janoshnosh]

@cirox
keine sorge, zwei lösungsansätze sind immer besser als einer, außer es sind die gleichen
gruß janosch

[deskounlmtd]

Ok, wir (99,9% janoshnosh, 0,1% ich) haben es folgendermaßen gemacht:

PHP-Code:

var anzahl = 14;    
for (var i = 0; i < anzahl; i++) {    
     var thumb = _root['thumb'+i];    
     var tmpziel = 5 + i*70;   
     thumb.ziel = tmpziel;  
     thumb.id = i;  
     thumb.onEnterFrame = function () {  
          var fac = Math.ceil((this.ziel - this._x) / 6);    
          this._x += fac;  
          if (this._x == this.ziel) {  
               delete this.onEnterFrame;    
               if (this.id == 13) gotoAndStop(2);  
          }  
     }    
}
stop(); 


- steht im ersten Frame. In dem habe ich aus den Bitmaps nochmal MCs gemacht, diesmal ohne Animation. Instanzen von thumb0 bis thumb13.
(Jetzt hat jANosh mir verklickert, dass ich gar keine 2 Frames brauche, das wird dann noch geändert )
Danke an dieser Stelle nochmal an jANosh und seine selbstlose Hilfe ;-P

FLA hier downloaden!