Shaden von BitmapFileMaterial

[markus.freise]

Hi,

ich steige gerade in die Wunderwelt von Flash und 3D ein. Dabei habe ich ein Problem: Wenn ich BitmapFileMaterial nutze, wird mir die entsprechende Plane nicht geshadet. Alle weiteren Planes, die einfach ein GourardMaterial bekommen, spielen aber wunderbar mit.

Es geht um diesen Teil des Codes:

...

var b1:BitmapFileMaterial = new BitmapFileMaterial("fotolia_39374_breit_1.jpg",true);
b1.doubleSided = true;
var b2:BitmapFileMaterial = new BitmapFileMaterial("fotolia_39374_breit_2.jpg",true);
b2.doubleSided = true;
var b3:BitmapFileMaterial = new BitmapFileMaterial("fotolia_39374_breit_3.jpg",true);
b3.doubleSided = true;

var m1:GouraudMaterial = new GouraudMaterial(light,0xCCCCCC,0xCCCCCC);
m1.doubleSided = true;
var m2:GouraudMaterial = new GouraudMaterial(light,0xCCCCCC,0xBBBBBB);
m2.doubleSided = true;
var m3:GouraudMaterial = new GouraudMaterial(light,0xEEEEEEc,0x000000);
m3.doubleSided = true;

obj1 = new DisplayObject3D();

vorderseite = new Plane(b3, 600, 600, 1, 1);
erste_innenseite = new Plane(m3, 600, 600, 1, 1);
letzte_innenseite = new Plane(m3, 600, 600, 1, 1);
rueckseite = new Plane(b1, 600, 600, 1, 1);
ruecken = new Plane(b2, 180, 600, 1, 1);

...

Danke für Eure Hilfe!

--

Markus Freise . code-x GmbH . Technologiepark 9 . Paderborn . www.code-x.de

[Majo]

hi und willkommen im FF,
hast du denn auch ein Licht zur Scene geadded?

[Majo]

sieht so aus als ob es mit BitmapFileMaterial nicht geht,
also Bild laden oder aus der Biliothek adden.
isch hab da ma was vorbereitet

package {
	import org.papervision3d.objects.primitives.Plane;
	import org.papervision3d.view.BasicView;
	import org.papervision3d.materials.shadematerials.GouraudMaterial;
	import org.papervision3d.materials.BitmapFileMaterial;
	import org.papervision3d.materials.BitmapMaterial;
	import org.papervision3d.materials.shaders.PhongShader;
	import org.papervision3d.materials.shaders.ShadedMaterial; 
	import org.papervision3d.events.InteractiveScene3DEvent;
	import org.papervision3d.lights.PointLight3D;
	
	import flash.events.Event;
	import flash.display.BitmapData;

	public class ShaderDemo extends BasicView {
		private var light:PointLight3D;
		
		public function ShaderDemo(viewportWidth:Number=600,viewportHeight:Number=400,scaleToStage:Boolean=true,interactive:Boolean=true, cameraType:String = "Free") {
			super(viewportWidth,viewportHeight,scaleToStage,interactive, cameraType);
			iniObjects();
			//renderer.renderScene(scene, camera, viewport);
			startRendering();
		}
		
		
		private function _ROLL_OVER(e:InteractiveScene3DEvent):void {
			trace("ROLL_OVER");
			viewport.buttonMode = true;
		}
		private function _ROLL_OUT(e:InteractiveScene3DEvent):void {
			trace("ROLL_OUT");
			viewport.buttonMode = false;
		}

		private function _CLICK(e:InteractiveScene3DEvent):void {
			trace("Clicked: " + e.target);
		}


		private function iniObjects():void {
			light = new PointLight3D(false);
			light.x = 200;
			light.z = -400;
			light.y = 10;
			

			var bmp:BitmapData = new side1(0,0) as BitmapData; //side1 ist der verknüpfungsname des bildes in der bibliothek...optinal kannst du es auch laden, musst dann aber erst warten bis das bild geladen ist
			var b1:BitmapMaterial = new BitmapMaterial(bmp);
			b1.doubleSided = true;
			
			var m1:GouraudMaterial = new GouraudMaterial(light,0xCCCCCC,0xCCCCCC);
			m1.doubleSided = true;
			
			var shader:PhongShader = new PhongShader(light, 0xffffff, 0x000000, 10);
			var shadedMaterial:ShadedMaterial = new ShadedMaterial(b1, shader);
			
			var vorderseite = new Plane(shadedMaterial, 600, 600, 1, 1);
			vorderseite.x = -300;
			scene.addChild(vorderseite);
			var erste_innenseite = new Plane(m1, 600, 600, 1, 1);
			erste_innenseite.x = 300;
			scene.addChild(erste_innenseite);
			
			addEventListener(Event.ENTER_FRAME, onEnterFrame);
         
         
			 function onEnterFrame(e:Event):void
			 {
				light.x = stage.mouseX;
				light.y = stage.mouseY;
				renderer.renderScene(scene, camera, viewport);
			 }
		}
	}
}

[markus.freise]

Oh, Klasse. Danke. Das scheint der richtige Ansatz zu sein. Da macht man mal zwei Jahre nichts großes mit Flash und schon verliert man den Anschluss.