planes anklickbar machen

[THA_BEST]

hey,

wie bekomme ich einen plane so das er anklickbar wird
und dann auf ein bild in die zeitleiste springt

und das in AS3

so gotoandstop style

[Basti-n]

Guten Tag,
vielleicht nächstes mal noch nen bisschen Code damit man besser versteht was genau dein Problem ist.

Aber ich Versuchs mal

Also wie ich raus lesen kann, arbeitest du in Flash CS4 und mit Papervision3D.
um eine Plane an klickbar zu machen musst du deine:
Viewport3D.interactive = true;
Viewport3D.buttonMode = true;

um deiner Plane ein MouseEvent hinzuzufügen gibt es 2 Wege:

PHP-Code:

//1.) InteractiveScene3DEvent:
plane.addEventListener(InteractiveScene3DEvent.OBJECT_CLICK, planeClicked);

function planeClicked(e:InteractiveScene3DEvent):void
{
       gotoAndStop(30); //30 ist hier das Bild in der Zeitleiste auf welches du springst.
}

//2.) Plane mit MovieMaterial über MovieClip steuern:
// "derMc" ist eine instanz eines MovieClips auf deiner Bühne.
var mm:MovieMaterial = new MovieMaterial(derMc,false,true);
mm.interactive = true;
mm.animated = true;
mm.smooth = true;
mm.doubleSided = true;
var p:Plane = new Plane(mm, 200, 200, 4, 4);
scene.addChild(p);//scene ist deine scene3D die du ja vorher irgendwo erstellt hast...

//und dann einfach dein MouseEvent auf den MovieClip:
derMc.addEventListener(MouseEvent.CLICK, planeClicked);
function planeClicked(e:MouseEvent):void
{
       gotoAndStop(30); //30 ist hier das Bild in der Zeitleiste auf welches du springst.
} 


Ich empfehle dir aber bevor du mit Papervision3D anfängst dich erstmal mit den Grundlagen in As3 und der Objektorientierten Programmierung zu befassen.

Ich hoffe ich konnte helfen
mfg. Basti

[THA_BEST]

danke für die antwort

ich weiss nur nicht genau wohin ich das machen kann

ich hab mir zwei tutorials gekauft von cartoonsmart.com

wo halt erklärt wird wie ich diese planes mache aber nicht wie man sie anklickt
dann waren die tutorials auf english also auch nicht grade einfach alles zu verstehen:

ich geb dir mal meine zwei skripts dafür und wäre echt cool wenn du mir zeigen kannst wo ich genau das hinschreiben soll und ob du andere fehler findest

PHP-Code:

package
{
    
    import flash.display.Sprite;
    import flash.events.Event;
    
    import org.papervision3d.view.Viewport3D;
    import org.papervision3d.cameras.Camera3D;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.render.BasicRenderEngine;
    
    public class PV3dBase extends Sprite
    {
            public var viewport: Viewport3D;
            public var camera: Camera3D;
            public var scene: Scene3D;
            public var render: BasicRenderEngine;
            
        public function init(vpWidth:Number = 1000, vpHeight:Number = 1000):void
        {
            
            initPV3d(vpWidth, vpHeight);
            init3d();
            init2d();
            initEvents();
        }

        protected function initPV3d(vpWidth:Number, vpHeight:Number):void
        {
            
            viewport =     new Viewport3D();
            camera =         new Camera3D();
            scene =             new Scene3D();
            render =         new BasicRenderEngine();
            
            addChild(viewport);
        }
        
        protected function init3d():void
        {
            
        }
        
        protected function init2d():void
        {
            
        }
        
        protected function initEvents():void
        {
            addEventListener(Event.ENTER_FRAME, onFrameEnter)
        }
        
        protected function onFrameEnter(e:Event):void
        {
            render.renderScene(scene, camera, viewport);
            animation();
        }
        
        protected function animation():void
        {
            
        }
    }
} 


und jetzt der wo meine planes gemacht werden:

PHP-Code:

package
{    
    import PV3dBase;
    import org.papervision3d.objects.primitives.Plane;
    import org.papervision3d.materials.BitmapFileMaterial;
    
    public class zoom3d extends PV3dBase
    {        
        protected var p:Plane;
        protected var p1:Plane;
        protected var bfm:BitmapFileMaterial;
        protected var bfm1:BitmapFileMaterial;
        
        public function zoom3d()
        {
            bfm = new BitmapFileMaterial("alicia1.jpg");
            bfm.oneSide = false;
            bfm.smooth = true;
            bfm1 = new BitmapFileMaterial("alicia2.jpg");
            init();
        }
        
        override protected function init3d():void
        {
            p1= new Plane(bfm1, 192, 192, 5, 5);
            scene.addChild(p1);
            p1.x = 0;
            p1.y = 0;
            p1.z = 0;
            
            camera.target = p1;
            var i:uint;
            
            for(i=0; i<80; i++)
            {
                p = new Plane(bfm, 192, 192, 5, 5);
                scene.addChild(p);
            
                p.x = Math.random()* 1000-800;
                p.z = Math.random()* 1000-800;
                p.y = Math.random()* 1000-800;
                p.rotationY = Math.random()* 360;
                
            }
        }
        
        override protected function animation():void
        {
            camera.x = stage.mouseX*5.5;
            camera.y = stage.mouseY*5.5;
            camera.z = (stage.mouseY*5.5) - stage.stageWidth;
        }
    }
} 


[Basti-n]

Netter haufen Codesalat^^
sieht so aus als hättest du ungefair 0 ahnung von As3.

Ich empfehle dir nochmal DRINGENST dich erst mit den Grundlagen in As3 zu befassen bevor du mit Papervision 3D anfängst! aber na gut:

also ich würde erstmal alles in eine Klasse und nicht in 2 schreiben.
Dann eine initPv3d Methode zum erstellen deiner Papervision viewport, scene, camera und BasicRenderEngine.
Dann eine initPlanes Methode in der deine Planes erstellt und zur scene hinzugefügt werden.
Dann dein loop, also deine Methode die beim enter_frame event gefeuert wird.

hier mal das ganze in meiner version:

PHP-Code:

package
{
    import flash.display.Sprite;
    import flash.events.Event;
    
    import org.papervision3d.cameras.Camera3D;
    import org.papervision3d.materials.BitmapAssetMaterial;
    import org.papervision3d.objects.primitives.Plane;
    import org.papervision3d.render.BasicRenderEngine;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.view.Viewport3D;
    
    public class zoom3D extends Sprite
    {
        private var vp:Viewport3D;
        private var scene:Scene3D;
        private var cam:Camera3D;
        private var render:BasicRenderEngine;
        private var plane1:Plane;
        private var plane2:Plane;
        
        public function zoom3D()
        {
            initPv3d();
            initPlanes();
            this.addEventListener(Event.ENTER_FRAME, loop);
        }
        
        private function initPv3d():void
        {
            vp = new Viewport3D(0,0,true,true);
            this.addChild(vp);
            
            scene = new Scene3D();
            cam = new Camera3D();
            cam.zoom = 100;
            
            render = new BasicRenderEngine();
        }
        
        private function initPlanes():void
        {
            //erstes Material erstellen
            var bam1:BitmapAssetMaterial = new BitmapAssetMaterial("alicia1.jpg");
            bam1.smooth = true;
            bam1.interactive = true;
            bam1.doubleSided = true;
            
            //zweites Material erstellen
            var bam2:BitmapAssetMaterial = new BitmapAssetMaterial("alicia2.jpg");
            bam2.smooth = true;
            bam2.interactive = true;
            bam2.doubleSided = true;
            
            //plane2 mit zweitem material, also Bild2 erstellen und zu scene hinzufügen
            plane2 = new Plane(bam2, 192, 192, 5, 5);
            scene.addChild(plane2);
            
            //80 mal(in schleife) eine neue plane erstellen mit dem ersten material und position sowie 
            //Winkel zufällig bestimmen lassen. Dann die Planes auf zur scene hinzufügen.
            for(var i:uint=0; i<80; i++)
            {
                plane1 = new Plane(bam1, 192, 192, 5, 5);
                scene.addChild(plane1);
            
                plane1.x = Math.random()* 1000-800;
                plane1.z = Math.random()* 1000-800;
                plane1.y = Math.random()* 1000-800;
                plane1.rotationY = Math.random()* 360;
            }
        }
        
        private function loop(e:Event):void
        {    
            //camera Position an Mausposition anpassen:
            cam.x = stage.mouseX*5.5;
            cam.y = stage.mouseY*5.5;
            cam.z = (stage.mouseY*5.5) - stage.stageWidth;
            
            //rendern der Scene:
            render.renderScene(scene,cam,vp);
        }
    }
} 


Code hab ich jetzt nich nochma getestet aber sollte laufen!


Hier nochma ne page zu as3 grundlagen etz. auch lerning bei doing das meiste und auch zu Papervision. (und ist sogar alles kostenlos!).
gotoandlearn.com - Free video tutorials by Lee Brimelow on the Flash Platform

Ich hoffe ich konnte helfen und möchte dich bitten in zukunft erst mal im internet zu suchen und dich mit den GRUNDLAGEN IN AS3 zu befassen bevor du netten forenmitgliedern wie mir die Zeit raubst

mfg. Basti

[THA_BEST]

hey basti

danke für deine hilfe

ich kriege aber so ne fehler meldung?

was mach ich falsch?

INFO: Viewport autoScaleToStage : Papervision has changed the Stage scale mode.
INFO: Papervision3D 2.0.0 (March 12th, 2009)

ReferenceError: Error #1065: Variable jpg ist nicht definiert.
at global/flash.utils::getDefinitionByName()
at org.papervision3d.materials::BitmapAssetMaterial/createBitmapFromLinkageID()
at org.papervision3d.materials::BitmapAssetMaterial/set texture()
at org.papervision3d.materials::BitmapAssetMaterial()
at zoom3D/initPlanes()
at zoom3D()

[THA_BEST]

hab es jetzt hinbekommen

aber egal wo ich den viewport.interactive = true;
viewport.buttonMode = true;

hinsetze er gibt mir immer einen fehler:1120: Access of undefined property viewport.


Viewport3D.interactive = true;
Viewport3D.buttonMode = true;

und so geschrieben bekomme ich auch nen fehler.

[milchreis]

jetzt siehst du wohl in deinem eigenen Code nciht mehr durch?

du hast doch gar kein viewport, das heißt bei dir vp.


die as tutorials von der Seite sind nicht so dufte.

[THA_BEST]

oh man

ich hab jetzt mein alten script genommen hab es hinbekommen mit dem viewport

und den button mode

jetzt schaff ich die verlinkung nicht!

PHP-Code:

package {
    import flash.display.MovieClip;
    import flash.events.*;
    
    import PV3dBase;
    import org.papervision3d.objects.primitives.Plane;
    import org.papervision3d.materials.BitmapFileMaterial;
    import org.papervision3d.events.InteractiveScene3DEvent;
    import org.papervision3d.materials.MovieAssetMaterial;
    
    public class zoom3d extends PV3dBase {
        protected var p:Plane;
        protected var p1:Plane;
        

        protected var movieMat: MovieAssetMaterial;
        protected var movieMat1: MovieAssetMaterial;
        
        protected var alicia1:MovieClip = new MovieClip()
        protected var alicia2:MovieClip = new MovieClip()


        public function zoom3d() {

            movieMat1 =  new MovieAssetMaterial("alicia1", true, true);
            movieMat1.doubleSided = true;
            //movieMat.interactive = true;
            //movieMat.animated = true;
            
            alicia1 = MovieClip(movieMat1.movie);
            
            movieMat =  new MovieAssetMaterial("alicia2", true, true);
            movieMat.doubleSided = true;
            //movieMat.interactive = true;
            //movieMat.animated = true;
            
            alicia2 = MovieClip(movieMat.movie);
            
            
            /*bfm=new BitmapFileMaterial("alicia1.jpg");
            bfm.oneSide=false;
            bfm.smooth=true;
            bfm1=new BitmapFileMaterial("alicia2.jpg");*/
            init();
        }

        override protected function init3d():void {
            viewport.interactive = true;
            viewport.buttonMode = true;

            p1=new Plane(movieMat1,100,100,2,2);
            scene.addChild(p1);
            p1.x=0;
            p1.y=0;
            p1.z=50;

            camera.z=0;
            camera.target=p1;
            p1.z=3;
            var i:uint;

            for (i=0; i<50; i++) {
                p=new Plane(movieMat,100,100,2,2);
                scene.addChild(p);

                p.x=Math.random()*1600-800;
                p.z=Math.random()*1600-800;
                p.y=Math.random()*1600-800;
                p.rotationY=Math.random()*360;
                p.rotationX=Math.random()*360;
                
                alicia1.addEventListener(MouseEvent.CLICK, planeClicked);  

 function planeClicked(e:MouseEvent):void 
{ 
       gotoAndStop(100); //30 ist hier das Bild in der Zeitleiste auf welches du springst. 
                }
            }
        }

        override protected function animation():void {
            camera.x=stage.mouseX*1.5;
            camera.y=stage.mouseY*1.5;
            camera.z = (stage.mouseY*1.5) - stage.stageWidth;
        }

    }
} 


help help help

das ist die fehlermeldung:
1180: Call to a possibly undefined method gotoAndStop.
Warning: 1060: Migration issue: The method gotoAndStop is no longer supported. For more information, see MovieClip.gotoAndStop()..


ich will es echt lernen aber immer ein mist fehler

@milchreis ich geb dir auch zimt und zucker
aber ich brauch hilfe

[milchreis]

Zitat von THA_BEST

@milchreis ich geb dir auch zimt und zucker
aber ich brauch hilfe

Ich hab dir gesagt was oben den Fehler ausgelößt hat und nun nimmst du wieder ein anderes script? Wäre schön wenn wir mal bei einem bleiben würden.

Deine letzte Klasse extended PC3dbase, Ich _vermute_ das diese, wie die im Internet zu findenden anderen base Klassen, Sprite extended.

Oder kurz ausgedrückt: Du stehst vor der Mona Lisa und suchst nach dem "Play" Knopf.
Du solltest also die methode auf dem Movieclip abspielen der auch abgespielt werden soll.

[THA_BEST]

Also ich belass es jetzt bei meinen 2 scripts weil ich so gesehn zwei drittel von meinem problem gelöst habe.

ich wollte 3 dinge haben ein 3D raum dann Planes im 3D raum und dann wollte ich auf die Planes klicken können um auf ein anderes bild zu gelangen auf der zeitleiste

Die ersten beiden dinge haben geklappt nur das letzte bekomme ich nicht hin.

Von einem Tutorial und von Basti-N habe ich diesen Satz gelesen:

plane.addEventListener(MouseEvent.CLICK, planeClicked);

function planeClicked(e:MouseEvent):void
{
gotoAndStop(100);
}
}

Eigentlich müsste es ja klappen da bei allen Tutorials und quellen wo ich es sehe geklappt hat.

Egal wieviel ich versuche zu ändern es wird der selbe fehler angezeigt!

Könnte mir jemand den nötigen code posten und mir sagen an welcher stelle ich ihn schreiben müsste.

Danke für die Tips und hilfe die ich bis jetzt bekommen habe.

[Basti-n]

Also ich finds zwar langsam ne echte frechheit,

und ich hab mich während ich deine "Galerie" programmiert habe echt aufgeregt, es kann doch nicht sein, dass du hier her kommst um dir dein Programm schreiben zu lassen. Andere nehmen dafür Geld! Aber ich bin ma wider zu freundlich..., Hier:

PHP-Code:

package
{
    import flash.display.Sprite;
    import flash.events.Event;
    
    import org.papervision3d.cameras.Camera3D;
    import org.papervision3d.events.InteractiveScene3DEvent;
    import org.papervision3d.materials.BitmapAssetMaterial;
    import org.papervision3d.objects.DisplayObject3D;
    import org.papervision3d.objects.primitives.Plane;
    import org.papervision3d.render.BasicRenderEngine;
    import org.papervision3d.scenes.Scene3D;
    import org.papervision3d.view.Viewport3D;
    
    public class zoom3D extends Sprite
    {
        private var vp:Viewport3D;
        private var scene:Scene3D;
        private var cam:Camera3D;
        private var render:BasicRenderEngine;
        private var plane2:Plane;
        
        public function zoom3D()
        {
            initPv3d();
            initPlanes();
            this.addEventListener(Event.ENTER_FRAME, loop);
        }
        
        private function initPv3d():void
        {
            vp = new Viewport3D(0,0,true,true);// interactive = true ist hiermit erledigt!
            vp.buttonMode = true;
            this.addChild(vp);
            
            scene = new Scene3D();
            cam = new Camera3D();
            cam.target = DisplayObject3D.ZERO;
            cam.zoom = 100;
            
            render = new BasicRenderEngine();
        }
        
        private function initPlanes():void
        {
            //erstes Material erstellen
            var bam1:BitmapAssetMaterial = new BitmapAssetMaterial("alicia1.jpg");
            bam1.smooth = true;
            bam1.interactive = true;
            bam1.doubleSided = true;
            
            //zweites Material erstellen
            var bam2:BitmapAssetMaterial = new BitmapAssetMaterial("alicia2.jpg");
            bam2.smooth = true;
            bam2.interactive = true;
            bam2.doubleSided = true;
            
            //plane2 mit zweitem material, also Bild2 erstellen und zu scene hinzufügen
            plane2 = new Plane(bam2, 500, 500, 2, 2);
            plane2.z = + 1000;
            plane2.addEventListener(InteractiveScene3DEvent.OBJECT_CLICK, p2Click);
            scene.addChild(plane2);
            
            //80 mal(in schleife) eine neue plane erstellen mit dem ersten material und position sowie 
            //Winkel zufällig bestimmen lassen. Dann die Planes auf zur scene hinzufügen.
            for(var i:uint=0; i<20; i++)
            {
                   var plane1:Plane = new Plane(bam1, 192, 192, 3, 3);
                plane1.addEventListener(InteractiveScene3DEvent.OBJECT_CLICK, onClick);
                scene.addChild(plane1);
            
                plane1.x = Math.random()* 800 -400;
                plane1.z = Math.random()* 800 + 100;
                plane1.y = Math.random()* 800 -400;
                plane1.rotationY = Math.random()* 360;
            }
        }
        private function onClick(e:InteractiveScene3DEvent):void
        {
            cam.target = e.currentTarget as DisplayObject3D;
        }
        private function p2Click(e:InteractiveScene3DEvent):void
        {
            cam.target = DisplayObject3D.ZERO;
        }
        
        private function loop(e:Event):void
        {    
            //camera Position an Mausposition anpassen:
            cam.x = (stage.mouseX*2)-800 ;
            if(stage.mouseY > 100)//nicht zu dicht ran..
            {
                cam.zoom = (((1 / this.mouseY)*50)*500)+50;
            }
            
            //rendern der Scene:
            render.renderScene(scene,cam,vp);
        }
    }
} 


Ich möchte dich bitten von nun für etwa nen jahr oder zwei die finger von papervision3D zu lassen und erstmal mit actionScript anzufangen!

Hier ne gute dvd dazu. Wenn du schon Geld für tuts ausgibst dann bitte für gute!
Flash-Programmierung mit ActionScript 3. Für Ein- und Umsteiger - Das Video-Training von Galileo Design

vllt schaffst du's ja auch schneller als in nem Jahr.

mfg. Basti

[Basti-n]

Hier noch ne kleine Beispieldatei.

Für mich is das Thema damit abgeschlossen.

[ING]

Zitat von Basti-n

und ich hab mich während ich deine "Galerie" programmiert habe echt aufgeregt, es kann doch nicht sein, dass du hier her kommst um dir dein Programm schreiben zu lassen.

lol, selbst schuld

[Basti-n]

mhm ING, sind deine 100 Beiträge alle so sinnvoll?

jaa, ich helfe andere selbst wenn ich mich drüber aufrege... kennst du wohl nicht so

mfg. Basti

[THA_BEST]

Danke nochmals an alle die die versucht haben mir zu helfen.

Ich wollte wirklich nicht das mir jemand das ganze ding schreibt, hab so gut ich konnte alles selber versucht zu machen bin aber nicht so weit gekommen wie ich wollte deswegen dachte ich mir frag ich eben nach ob mir jemand helfen kann.

Bin da sehr Naiv ans thema gegangen.

Also ich wollte nicht frech sein

danke nochmals