[shin10]

ja das mit den bildern für den stuhl

ich hab hier mal die funktion stuhlZeichnen() in Stuhl.as angepasst:

PHP-Code:

package Raum{//Raum ist der unterordner in dem sich die .as-datei befinden muss (groß-/kleinschreibung beachten!)
    //im gegensatz zu framescripts müssen bei eigenen klassen ALLE benötigten klassen hinzugefügt werden!
    import flash.display.SimpleButton;
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.events.MouseEvent;
    import flash.utils.getDefinitionByName;
    import flash.display.Bitmap;
    import flash.display.BitmapData;
    import Raum.Tisch;
    import Raum.TischGruppe;
    import flash.display.Bitmap;
    
    public class Stuhl extends SimpleButton{
        private static var _stuhlListe:Array = new Array();
        private var id:uint;
        public static const BREITE = 12;
        public static const HÖHE = 13;
        public function Stuhl(stuhlName:String=""):void{
            id = _stuhlListe.length;
            _stuhlListe.push(this);
            //diese funktion wird beim erstellen des Objekts ausgeführt
            if(stuhlName!=""){
                name = stuhlName;
            }
            //
            
            this.upState = stuhlZeichnen("platz_frei", "platz_reserviert");
            this.downState = stuhlZeichnen("platz_ausgewaehlt");
            this.overState = stuhlZeichnen("platz_rollover");
            this.hitTestState = stuhlZeichnen("platz_frei");
            
            this.addEventListener(MouseEvent.CLICK, clickHandler);
        }
        private var _reserviert:Boolean = false;
        private function clickHandler(e:MouseEvent):void{
            reservierung(!_reserviert);//toggle der reservierung
        }
        public function get reserviert():Boolean{
            return _reserviert;
        }
        public function set reserviert(val:Boolean):void{
            reservierung(val);
        }
        private function reservierung(val:Boolean):void{
            _reserviert = val;
            this.upState = stuhlZeichnen("platz_frei", "platz_reserviert");
            var pn:String = getParentNames();
            _reserviert ? trace(pn+", "+name+"("+id+") wurde reserviert.") : trace("Die reservierung für "+pn+", "+name+"("+id+") wurde storniert.");
        }
        private function stuhlZeichnen(free:String, res:String=null):Sprite{
            var mc:Sprite = new Sprite();
            if(res!=null && _reserviert){
                var className:String = res;
            }else{
                className = free;
            }
            var cl:Class = getDefinitionByName(className) as Class;
            var bmpd:BitmapData = new cl(0,0);
            var bmp:Bitmap = new Bitmap(bmpd);
            bmp.x -= bmp.width*.5;
            bmp.y -= bmp.height*.5;
            mc.rotation = 180;
            mc.addChild(bmp);
            return mc;
        }
        private function getParentNames():String{
            var pn:Array = new Array();
            if(parent is Tisch){
                pn.unshift(parent.name);
                if(parent.parent is TischGruppe){
                    pn.unshift(parent.parent.name);
                }
            }else if(parent is Balkonreihe){
                pn.unshift(parent.name);
                if(parent.parent is Balkon){
                    pn.unshift(parent.parent.name);
                }
            }
            return pn.join(", ");
        }
        public static function get stuhlListe():Array{
            return _stuhlListe;
        }
    }
} 


die bilder dafür musst du mit den entsprechenden namen in die bibliothek deiner fla ziehen.
dann gehst du bei jedem bild auf eigenschaften und setzt beide häkchen:
1. exportieren für actionscript
2. exportieren in erstes frame

beim klassennamen musst du unbedingt noch .png löschen

mfg

sx