loadMovie und ein onEnterFrame-Event sind technisch veraltet. Nimm besser eine MovieClipLoader-Instanz:
PHP-Code:
var index:Number = 0;
var urls:Array = new Array("film1.swf", "film2.swf");//etc
var targets:Array = new Array();
var picAnzahl:Number = urls.length;
//MCs erstellen
for(var i:Number=0;i<picAnzahl;i++){
this.targets.push(this.createEmptyMovieClip("con"+(i+1),(i+1)));
}
//Listener erstellen
var mclListener:Object = new Object();
var mcLoader:MovieClipLoader = new MovieClipLoader();
mcLoader.addListener(mclListener);
//und ersten Film mit loadClip laden
mcLoader.loadClip(urls[index], targets[index]);
//während des Ladens bspw. um Ladebalken o.ä. zu aktualisieren
mclListener.onLoadProgress = function(target:MovieClip, bytesLoaded:Number, bytesTotal:Number):Void {
var prozent = int(bytesLoaded*100/bytesTotal);
_root.ladebalkenMC.gotoAndStop(prozent);
}
//Laden fertig, MC ist befüllt
mclListener.onLoadInit = function(mc:MovieClip) {
index++;
if (index < urls.length) {//nächster
mcLoader.loadClip(urls[index], targets[index]);
}
else{//letzter geladen
getURL("home.html", "_self");
}
}