[figure8]

achso, haha. ich sehe, was dein fehler ist. schau mal:

var _swfLoader:Loader;
var _swfContent:MovieClip;
 
loadSWF("01.swf");
 
function loadSWF(path:String):void {
    var _req:URLRequest = new URLRequest();
    _req.url = path;
 
    _swfLoader = new Loader();
    setupListeners(_swfLoader.contentLoaderInfo);
   
    _swfLoader.load(_req);
}
 
function setupListeners(dispatcher:IEventDispatcher):void {
    dispatcher.addEventListener(Event.COMPLETE, addSWF);
    dispatcher.addEventListener(ProgressEvent.PROGRESS, preloadSWF);
}
 
function preloadSWF(event:ProgressEvent):void {
    var _perc:int = (event.bytesLoaded / event.bytesTotal) * 100;
    // swfPreloader.percentTF.text = _perc + "%";
}
 
function addSWF(event:Event):void {
    event.target.removeEventListener(Event.COMPLETE, addSWF);
    event.target.removeEventListener(ProgressEvent.PROGRESS, preloadSWF);
   
    _swfContent = event.target.content;
    _swfContent.addEventListener("close", unloadSWF);
 
    addChild(_swfContent);
}
 
function unloadSWF(event:Event):void {
    _swfLoader.unloadAndStop();
   
    removeChild(_swfContent);
    _swfContent = null;
} 

Quelle

hier wird ein clip namens "_swfContent" erstellt, der sozusagen deine swf ist, weil er mit dem CONTENT des loader-objekts referenziert wird.
du hingegen addest den loader lediglich in einem clip und müsstest, wenn du deinen code nicht ändern willst, das ganze so ansprechen:

swfcontent.getChildAt(0).content.meineFunktion(); 

ist natürlich super-uncool, deswegen versuch einfach, mein script-snippet zu benutzen..