Zitat:
Zitat von mauci  ja, klar, ist ja dein code.... |
… und ziemlich aaaaaaaaaaalt
Zitat:
Zitat von mauci die checkbox hat den instanznamen chkNewsletter und steckt im mcFormular. |
Also wie du schon selber schreibst, die Checkbox befindet sich in einem
MovieClip mit dem Instanznamen "mcFormular".
Erster Fehler: anstatt "mcFormular" hast du nur "mc" geschrieben, der Pfad
zur Checkbox stimmt also nicht.
Zweiter Fehler: die "fncInit()" Funktion war und ist dafür gedacht, alle Felder
des Formulars auf die Ausgangseinstellung zurückzusetzen. Also solltest du
dort deinen Befehl für die Checkbox unterbringen.
Versuch mal folgenden Code:
PHP-Code:
///////////////////////////////////////////////////////////////////////////////
//
var txtFieldObject:Object = new Object();
txtFieldObject.tf0 = {instName:"txtName", label:"Name", pflicht:1, tab:1};
txtFieldObject.tf1 = {instName:"txtVorname", label:"Vorname", pflicht:0, tab:2};
txtFieldObject.tf2 = {instName:"txtStrasse", label:"Straße", pflicht:0, tab:3};
txtFieldObject.tf3 = {instName:"txtOrt", label:"PLZ/Ort", pflicht:0, tab:4};
txtFieldObject.tf4 = {instName:"txtTel", label:"Telefon", pflicht:0, tab:5};
txtFieldObject.tf5 = {instName:"txtFax", label:"Fax", pflicht:0, tab:6};
txtFieldObject.tf6 = {instName:"txtEmail", label:"Email", pflicht:1, tab:7};
txtFieldObject.tf7 = {instName:"txtWeb", label:"Website", pflicht:0, tab:8};
txtFieldObject.tf8 = {instName:"txtMessage", label:"Nachricht", pflicht:1, tab:9};
//
///////////////////////////////////////////////////////////////////////////////
//
TextField.prototype.setOldContent = function()
{
this.text = txtFieldObject["tf"+this.i].label;
};
//----------------------------------------------------------------------------
TextField.prototype.setOldTxtStyle = function()
{
this.border = true;
this.background = true;
this.textColor = "0x777777";
this.borderColor = "0xAAAAAA";
this.backgroundColor = "0xFFFFFF";
};
//----------------------------------------------------------------------------
TextField.prototype.setNewTxtStyle = function()
{
this.border = true;
this.background = true;
this.textColor = "0x000000";
this.borderColor = "0x003399";
this.backgroundColor = "0xB0B0FF";
};
//----------------------------------------------------------------------------
TextField.prototype.setFalseStyle = function()
{
this.border = true;
this.background = true;
this.textColor = "0xFFFFFF";
this.borderColor = "0xFF0000";
this.backgroundColor = "0xFF0000";
};
//----------------------------------------------------------------------------
TextField.prototype.checkForOldContent = function()
{
if (this.text == txtFieldObject["tf"+this.i].label) return true;
};
// ---------------------------------------------------------------------------
TextField.prototype.checkIfEmpty = function()
{
if (this.text == "") return true;
};
//
///////////////////////////////////////////////////////////////////////////////
//
fncInit = function ()
{
mcFormular.chkNewsletter.selected = false;
mcFormular.txtStatus.textColor = "0xFF0000";
mcFormular.txtStatus.text = "";
// ----------------------------------------------------------
for (var i in txtFieldObject)
{
mcFormular[txtFieldObject[i].instName].text = txtFieldObject[i].label;
mcFormular[txtFieldObject[i].instName].tabIndex = txtFieldObject[i].tab;
mcFormular[txtFieldObject[i].instName].setOldTxtStyle();
mcFormular[txtFieldObject[i].instName].i = txtFieldObject[i].tab-1;
// ------------------------------------------------------
mcFormular[txtFieldObject[i].instName].onSetFocus = function()
{
this.setNewTxtStyle();
if (this.checkForOldContent())
{
this.text = "";
}
};
// ------------------------------------------------------
mcFormular[txtFieldObject[i].instName].onKillFocus = function()
{
this.setOldTxtStyle();
if (this.checkIfEmpty())
{
this.setOldContent();
}
};
}
// ----------------------------------------------------------
mcFormular.btnClear.onRelease = function()
{
this.txtLabel._x = this.txtLabel._y -= 1;
fncInit();
};
mcFormular.btnSend.onRelease = function()
{
this.txtLabel._x = this.txtLabel._y -= 1;
fncSend(mcFormular);
};
};
//
///////////////////////////////////////////////////////////////////////////////
//
fncSend = function (mc)
{
var felderVoll:Boolean = true;
var trueEmail:Boolean = false;
for (var i in txtFieldObject)
{
if(txtFieldObject[i].pflicht)
{
if ((mc[txtFieldObject[i].instName].text == "") || (mc[txtFieldObject[i].instName].text == txtFieldObject[i].label))
{
mc[txtFieldObject[i].instName].setFalseStyle();
mc.txtStatus.text = "Bitte füllen Sie alle Felder korrekt aus!";
felderVoll = false;
}
// --------------------------------------------------------------------
if(txtFieldObject[i].instName == "txtEmail")
{
if ((mc[txtFieldObject[i].instName].text.indexOf("@")<2) || (mc[txtFieldObject[i].instName].text.indexOf(".")<1) && (mc[txtFieldObject[i].instName].text.indexOf(".")<5))
{
mc[txtFieldObject[i].instName].setFalseStyle();
mc.txtStatus.text = "Bitte füllen Sie alle Felder korrekt aus!";
trueEmail = false;
} else
{
trueEmail = true;
}
}
}
}
if(!txtFieldObject.tf6.pflicht) trueEmail = true;
// ------------------------------------------------------------------------
if ((felderVoll == true) && (trueEmail == true))
{
var receiveData:LoadVars = new LoadVars();
receiveData.onLoad = function(success)
{
getURL("javascript:alert('PHP GELADEN')");
if (success)
{
if (receiveData.infoOk)
{
getURL("javascript:alert('OK: EMAIL GESENDET')");
mc.txtStatus.textColor = "0x00CC00";
mc.txtStatus.text = "Daten wurden erfolgreich gesendet";
delete receiveData;
delete sendData;
restartInt = setInterval(function(){
clearInterval(restartInt);
fncInit();
}, 4000);
} else
{
getURL("javascript:alert('FEHLER: EMAIL NICHT GESENDET')");
mc.txtStatus.textColor = "0xFF0000";
mc.txtStatus.text = "Daten konnten leider nicht gesendet werden!";
}
}
};
//
var sendData:LoadVars = new LoadVars();
for (var j in txtFieldObject)
{
sendData[txtFieldObject[j].instName] = mc[txtFieldObject[j].instName].text;
}
//
sendData.chkNewsletter = mc.chkNewsletter.selected;
sendData.sendAndLoad("flashMail.php", receiveData, "POST");
mc.txtStatus.textColor = "0xFF0000";
mc.txtStatus.text = "Daten werden gesendet ...";
//
}
};
//
///////////////////////////////////////////////////////////////////////////////
//
mcFormular.btnClear.txtLabel.text = "löschen";
mcFormular.btnSend.txtLabel.text = "senden";
mcFormular.btnClear.txtLabel.textColor = "0xA8A8FF";
mcFormular.btnSend.txtLabel.textColor = "0xA8A8FF";
//----------------------------------------------------------------------------
mcFormular.btnClear.onRollOver = mcFormular.btnSend.onRollOver=function ()
{
this.txtLabel.textColor = "0xFFFFFF";
};
mcFormular.btnClear.onRollOut = mcFormular.btnSend.onRollOut=function ()
{
this.txtLabel.textColor = "0xA8A8FF";
};
//----------------------------------------------------------------------------
mcFormular.btnClear.onPress = mcFormular.btnSend.onPress=function ()
{
this.txtLabel._x = this.txtLabel._y += 1;
};
mcFormular.btnClear.onReleaseOutside = mcFormular.btnSend.onReleaseOutside=function ()
{
this.txtLabel.textColor = "0x000000";
this.txtLabel._x = this.txtLabel._y -= 1;
};
//
///////////////////////////////////////////////////////////////////////////////
//
fncInit();