[shorty]

So, ik hab dir auch mal schnell einen zurecht gebastelt. Meiner erhält seinen Playlist-Input aus ner XML. Die kannste ganz easy um die jeweiligen Track's erweitern, indem Du einfach eine neue zeile hinzufügst...

hier das script, und im Anhang der Player (1,34Kb ):

PHP-Code:

this.stop();
var tl:MovieClip = this;
//  Src. -------------------------------------------------------------------------------
var srcPlaylist:String = 'songs/playlist.xml';
//  Sound ------------------------------------------------------------------------------
_soundbuftime = 6;
var vol:Number = 80;
var trackID:Number = 0;
var sndOne:Sound = new Sound(tl);
//  #
function startStream():Void {
    var s:String = objXMLPlaylist.firstChild.childNodes[trackID].firstChild.nodeValue;
    sndOne.loadSound(s, true);
    sndOne.setVolume(vol);
}
//  Playliste --------------------------------------------------------------------------
var objXMLPlaylist:XML = new XML();
objXMLPlaylist.ignoreWhite = true;
objXMLPlaylist.onLoad = function(ok) {
    if (!ok) {
        trace('XML ERROR ID : ' + this.status);
    }
};
//  Volume -----------------------------------------------------------------------------
mcVolume.mcDrag.onPress = function() {
    this.onEnterFrame = function() {
        if (this._xscale >= 0 && this._xscale <= 100) {
            this._xscale = Math.round(mcVolume._xmouse * 100 / 190);
            this._xscale > 100 ? this._xscale = 100 : null;
            this._xscale < 1 ? this._xscale = 1 : null;
        }
        vol = this._xscale;
        sndOne.setVolume(vol);
    };
};
mcVolume.mcDrag.onRelease = mcVolume.mcDrag.onReleaseOutside = function () {
    delete this.onEnterFrame;
};
//  Buttons ----------------------------------------------------------------------------
btNext.onRelease = function() {
    trackID < objXMLPlaylist.firstChild.childNodes.length - 1 ? trackID++ : trackID = 0;
    startStream();
};
btStop.onRelease = function() {
    sndOne.stop();
};
btPlay.onRelease = function() {
    startStream();
};
//  Los :-)  ---------------------------------------------------------------------------
function Init():Void {
    mcVolume.mcDrag._xscale = vol;
    objXMLPlaylist.load(srcPlaylist);
}
Init(); 


viel spass,
shorty

Edit: hab noch n bischen drann geschraubt & verkürzt